“Journalism Game Scenario (CandW22 Inform 7 Workshop, Video 2)” by Dennis Jerz

The description of the player is "You are the brand new intern for the Greenstown Gazette."

The Gazette Newsroom is a room. "Exits lead north to the editor's office, and east to the lobby."

Your desk is scenery in the Gazette Newsroom.

On your desk is your press badge, your digital voice recorder, your camera, and your lunch.

Before taking something on the desk when Gruff's Office is not visited, try examining the noun.

The description of your press badge is "While wearing your press badge, you’ll be clearly identified as a reporter for the Greenstown Gazette."

Your press badge is wearable.

Instead of going somewhere when the player does not enclose the press badge, or the player does not carry the voice recorder, or the player does not carry the camera: say "But you're not fully equipped!"
	
The description of your voice recorder is "It's a little audio recording gadget, about the size of candy bar. Many reporters just use their phones, but Gruff warned you some places enforce 'no-gadget' zones, and some hostile authorities like to harass reporters by confiscating their phones. Either way, it's good to have a backup."

Your voice recorder is a device.

The description of your camera is "While it might feel more natural just to use your phone, some companies have rules about mixing your work stuff with your personal stuff on the same device. Besides, digital cameras have much better telephoto lenses."

The description of your lunch is "Being an ethical reporter means politely declining free meals and other gifts, as you learned on your very first day at the Gazzette. 'Check with me before you accept any gift that might even *potentially* look like a bribe,' Gruff had told you."

Your lunch is edible.

Gruff's Office is north of Gazette Newsroom. "You're in the editor's office. The newsroom is south."

Instead of exiting in Gruff's Office, try going south.
Instead of going outside in Gruff's Office, try going south. 
Instead of going nowhere in Gruff's Office, say "Gruff rubs his temples wearily. 'The exit is south, intern.'"

Nate Gruff is a man in Gruff's Office. "Nate Gruff, the Gazette's distinguished editor, is hard at work."

The description of Gruff is "He has a face for radio."

The protest flier is in Gruff's Office. The description of the protest flier is "It reads: 'Don’t let them risk your family’s health! Valley Power plans to double the voltage of the power lines running along the Difficult Run riverwalk. If your kids go to Riverside Middle School, their health is at risk! Come to City Hall at noon today, and ASK THE PROTESTORS ABOUT THE POWER LINES!'"

Understand "flyer" or "leaflet" or "paper" as the protest flier.

Every turn when the player can see Gruff: 
	say "[one of]'I see my favorite intern is all geared up. Protesters were handing out these fliers. Something about power lines.[or]'And yes, when I said you're my *favorite* intern, I was ware after that little incident you're now my *only* intern,' mutters Gruff. 'Off you go, now.'[or]Gruff projects the aura of a man who does not want to be disturbed.[stopping]";
	if the flier has not been carried by the player:
		say "[line break]Gruff is holding the flier for you to take.";
		
Before taking the flier for the first time:
	now the flier is in Gruff's Office;
	say "One more thing. I asked Lucas to print up a statement Valley Power just released. See him on your way out.'"

Instead of asking Gruff about "intern/little/incident/dangerous/accordion/fire/concertina", say "Gruff glowers. 'That was one dangerous accordion.'"

Instead of telling Gruff about "intern/little/incident/dangerous/accordion/concertina/fire", say "'It was a concertina,' you say. 'And it was already on fire.'[paragraph break]Gruff rolls his eyes. 'Have it your way,' he says, and returns to his work."

Gazette Lobby is east of the Gazette Newsroom. "Security doors lead west into the newsroom, and east into the business wing. Main Street is south." 

Lucas is a man in the Gazette Lobby. "Lucas is [one of]on the telephone.[or]giving you a friendly wave.[or]at his usual post.[cycling]"

Every turn when the player can see Lucas: 
	say "[one of]Seeing you, he covers the mouthpiece with his hand. 'Guy on the phone says he wants a full-page ad, but only if we give his shop a good review.'[or]With a sigh, Lucas returns to his call. 'If you'd like to talk about a reporting matter, I can connect you to an editor. But advertising is a different department.'[or]Lucas listens patiently to the caller. 'Well, sir, it's a bit like the separation of chuch and state. Would you say this is an *editorial* matter, or a *business* matter?'[or]'Very well, sir, I'll connect you right away,' says Lucas.[or][stopping]";
	if the printout is nowhere:
		say "[line break]He taps a printout. 'This is for you,' he says.";
		now the printout is in the Gazette Lobby.
		
A printout is nowhere.  The description of the printout is "It's a PR statement, dated today, attributed to Marian Luce, CEO of Valley Power.  It’s full of the usual upbeat PR stuff.[paragraph break]One relevant passage reads, 'Greenstown families have trusted Valley Power for generations, and our plans for safely and efficiently reimagining the riverwalk power distribution system are part of Greenstown’s tradition of respecting our environment while also meeting the growing needs of our vibrant community.'"

Understand "statement" or "paper" or "print" as the printout.

Before going south in the Gazette Lobby when the player can see Lucas: 
	if the player carries the printout: 
		say "Lucas, finger-gunning you amicably as you head for the, says, 'Go get 'em, tiger!'";
	else: 
		instead say "Lucas stops you by clearing his throat. 'The printout, intern? Gruff wanted you to take it.'";

The door to the newsroom is west of the Gazette Lobby. It is scenery. It is a door. West of it is the Gazette Newsroom. 

The door to the business wing is east of the Gazette Lobby. It is scenery. It is a door. East of it is the Business Office.
 
Before going east in the Gazette Lobby when the player can see Lucas, say "'Better stay in your lane, news intern,' says Lucas airily."

Instead of going east in the Gazette Lobby, say "You approach the door to the business wing, but it doesn't open. And why should it?  You work on the other side of the divide."

Instead of doing anything other than examining with Lucas, say "'Sorry, intern,' says Lucas, not looking up. 'These emails don't answer themselves. I know because I've tried that already.'"

Understand "wave at [something]" as waving.

Main Street is south of the Gazette Lobby. The description of Main Street is "You are on main street, which leads east towards City Hall, and west towards Riverside Park. The Greenstown Gazete office is north."