Shabby Office is a room. 

The description of the Shabby Office is "The neon sign across the street blinks through the blinds, slanting a stark pattern across your desk.

The only exit leads south."

The neon sign is scenery in the Shabby Office. The description of the neon sign is "In blinking neon: C... AS... IN... SIN... CASINO"

The view of the street, the blinds, the stark pattern of blinking light, and your desk are scenery in Shabby Office.

Your window is scenery in Shabby Office.

Before doing anything with the view of the street, now the noun is the neon sign.
Before doing anything with the stark pattern of blinking light, now the noun is the neon sign.
Before doing anything with the blinds, now the noun is the neon sign.

Before examining your window: now the noun is the neon sign.

Instead of doing anything with your window: say “You consider making your exit through the window, but set the thought aside. For now.”	

On your desk is a stack of bills and a bottle of whiskey. 

The description of the stack of bills is "Benny the Slug is not going to be happy if you don't come up with a C-note by tomorrow."

The description of the bottle of whiskey is "The label looked less blurry an hour or so ago, before she walked out of your life."

Understand "label" as the bottle of whiskey.

Instead of drinking the whiskey, say "You take another swig from the bottle of whiskey… but you still remember every detail."

Does the player mean drinking the bottle of whiskey: it is very likely.

The sound of hot jazz is in the office. "The sound of hot jazz floats up from the street below."

Instead of doing anything other than listening to the jazz, say "The sound of hot jazz is for listening to."

Instead of listening to the sound of hot jazz, say "Tiny Louie sounds a little off his game tonight."

Understand "tiny" or "louie" or "music" as the sound of hot jazz.

The Upper Hallway is south of the Shabby Office. "Your office is to the north and the janitor's closet is east. Stairs lead down to the street.”

A whiff of familiar perfume is in the Upper Hallway. "You catch a whiff of a familiar perfume."

Instead of doing anything except smelling with the familiar perfume, say "You'd be better of smelling it instead."

Instead of smelling the whiff of familiar perfume: 
	say "Lilac and vanilla. [first time]She must have lingered here after she stormed out.[paragraph break] [only][if the Swede's Cubby is not visited]A little stronger near the janitor's closet.[else]Fading fast, but not gone yet."
	
Understand "lilac" and "vanilla" as the whiff of familiar perfume.

Does the player mean smelling the perfume: it is very likely.

Instead of smelling the Upper Hallway: try smelling the familiar perfume.

The janitor's closet is scenery in the Upper Hallway.

Instead of doing anything with the janitor's closet, say "To do anything in the janitor's closet, you'd need to go east from here."

Instead of entering the janitor's closet, try going east.

The Swede's Cubby is east of the Upper Hallway.  "The Swede's janitorial cubby is just about the only thing on Bliss Alley that a fella might call clean."

A wastebasket is a container in the Swede's Cubby.

Inside the wastebasket is a diamond engagement ring. 

The description of the diamond engagement ring is "It still reads 'Moonlight Forever.'";

After taking the diamond engagement ring:
	now the whiff of perfume is scenery;
	say "Taken."

The diamond engagement ring is wearable.

After wearing the diamond engagement ring, say "You manage to get it partway onto your smallest finger."

Instead of taking off the diamond engagement ring, say "You can't quite get it past the knuckle... so it stays where it is, for now."

Bliss Alley is below the Upper Hallway. "Just another grimy street in this grimy city. Next to your sign, stairs lead up to your office and down to the Hard Knocks Lounge." 

The grimy city is scenery in Bliss Alley. "Just what you'd expect in a city full of little people fighting to feed their hungry dreams."

Understand "street", "grimy street", "grime", "people",  "little people", "hungry dreams" and "dreams" as the grimy city.

Gladhand Mick is a person in Bliss Alley. "From his post halfway down the stairs, Gladhand Mick eyes you suspiciously." 

Mick can be defensive or permissive. Mick is defensive.

Instead of going down in Bliss Alley when Mick is defensive, say "[one of]’No sir, Mr. Rockbottom,’ says Mick, blocking your path. 'Benny says no  more exceptions for you.’[or]’You gonna need a pass like everybody else,' says Mick. 'Especially after that incident with the accordion.'[or]Mick holds his ground. 'No pass, no entry.'[stopping]"

Instead of giving the pass to Gladhand Mick:
	say "Mick takes the pass and inspects it.[paragraph break]'It checks out. Benny's gonna be *real* glad to see you,' he says, stepping aside with professional courtesy.";
	now the pass is nowhere;
	now Mick is permissive.

Instead of showing the familiar pass to Gladhand Mick, say "[first time]'Will wonders never cease?’ marvels Mick. [only]'But ya gotta give it to me.'"

Instead of asking Mick to try doing something with a noun, try showing the noun to Mick.

Asking someone about something is speech. 
Telling someone about something is speech. 
Answering someone that something is speech. 
Asking someone for something is speech.

Instead of speech when the noun is Gladhand Mick:
	repeat through Table of Gladhand Mick's Commentary:
		if topic understood includes topic entry: 
			say "[commentary entry][paragraph break]"; 
			rule succeeds;
	say "Mick just scratches his head thickly.";

Table of Gladhand Mick's Commentary
topic	commentary
"pass/passes/ticket/tickets"	"'You give me a pass, I let you in,' says Mick. 'It ain't that hard.'"
"drink/whiskey/bottle"	"'Not a drop. Not while I'm on duty.'"
"yourself/himself/you"	"'I like to be the strong, silent type. When certain people gimme the chance,' he says."
"dream/dreams"	"'I'm living my dream right now,' says Mick. 'You oughta try it.'"
"accordion/incident"	"'Ain't nobody believes it was already on fire,' scoffs Mick. 'That just ain't right.'"

The Swede's Retreat is above the Upper Hallway. "The Swede tries to keep a little rooftop garden here."

A familiar looking pass is in the Swede's Retreat. The description of the familiar pass is "It's a pass to the Hard Knocks Lounge."

The Hard Knocks Lobby is below Bliss Alley.  "The contents of the Hard Knocks Lobby are TBD at the moment, but they should be impressive, because the player had to work to get here."